Overpass: Retrieve ways that are member of more than one multipolygon

Question

I'd like to find ways that are members of more than one type=multipolygon relation with role "outer" with Overpass API as this often indicates errors/problems. I'm not sure how to approach this correctly. This is how far I got:

relation({{bbox}})
  [type=multipolygon];
way(r:"outer");
rel(bw:"outer")(if:count(relations) > 1);
(._;>;);

out;

I start with multipolygon relations, look for their outer ways and try to find those ways parent relations where they have the role outer and look if there are more than one.

Alternatively I could also start with ways, but I thought it might be good to restrict the input set more:

way({{bbox}});
rel(bw:"outer")(if:count(relations) > 1);
(._;>;);

out;

I was not able to find any results and once I got an out of memory error. Is this somehow correct what I'm trying to do? Is this even possible with Overpass API?

Accepted Answer

I'm not sure it is the best way to do it, but one way to find them is to use a foreach statement to look through the relations one by one:

relation({{bbox}})[type=multipolygon]->.multis;
foreach.multis->.multi(
  // calculate outer ways of other multipolygons
  (.multis - .multi)->.others;
  way(r.others:"outer")->.otherways;
  // outer ways of current multi
  way(r.multi:"outer")->.multiways;
  // output ways in both sets
  way.multiways.otherways;
  out geom;
  );

http://overpass-turbo.eu/s/nsO

A slightly adjusted query eliminates the duplicates by collecting the found ways together in a set before outputting them:

relation({{bbox}})[type=multipolygon]->.multis;
foreach.multis->.multi(
  // calculate outer ways of other multipolygons
  (.multis - .multi)->.others;
  way(r.others:"outer")->.otherways;
  // outer ways of current multi
  way(r.multi:"outer")->.multiways;
  // collect found ways for output
  (way.multiways.otherways;.all;)->.all;
);
.all out geom;

http://overpass-turbo.eu/s/nsW

Answer 2

0

I am not good with Overpass, but could write a little program to extract them from a planet file, if you are not getting any answers here. Just open an issue on https://github.com/osmlab/fixing-polygons-in-osm .

permanent link

answered 13 Mar '17, 10:34

Jochen Topf
5.2k●5●50●74
accept rate: 31%

Thanks for the offer! This would be a possibility, but Overpass API has the advantage of minutely diffs that I can't easily setup for myself. This allows for some agile clean-up.

(13 Mar '17, 21:25) nebulon42

Overpass: Retrieve ways that are member of more than one multipolygon

Follow this question

Related questions