select boundaries around ways

Question

EDIT: using overpass-turbo

I have been looking for all shop=alcohol in Poland and finding their respective administration boundaries since the addresses are seldom complete.

So far I have this;

[out:json][timeout:3000];

{{geocodeArea:Poland}}->.searchArea;

node[shop="alcohol"](area.searchArea)->.posts;

foreach.posts(
  out;
  is_in;
  area._[admin_level~"[467]"];
  out ids;
);

// collect area details in 2nd step
.posts is_in;
area._[admin_level~"[467]"];
out;

which is almost a direct copy from this post https://help.openstreetmap.org/questions/35976/add-reverse-geocoding-information-to-the-overpass-resulting-set

however I also need to add ways, since many of the shops have been charted that way. Therefore I tried the following;

[out:json][timeout:3000];

{{geocodeArea:Poland}}->.searchArea;

node[shop="alcohol"](area.searchArea)->.posts;
way[shop="alcohol"](area.searchArea)->.posts;

foreach.posts(
  out;
  is_in;
  area._[admin_level~"[467]"];
  out ids;
);

// collect area details in 2nd step
.posts is_in;
area._[admin_level~"[467]"];
out;

However this bugs out and the auto help, well...doesn't.

Anyone?

Thanks in advance;

Accepted Answer

There are basically two issues in your second query:

Inputset union is needed to store all nodes and ways in .posts
is_in; does only work on nodes, that's why an additional recursion step is needed as well to turn ways into their respective nodes - namely (._;>;); and (.posts;>;); in the query below.

Here's how the query should look like:

[out:json][timeout:3000];

{{geocodeArea:Poland}}->.searchArea;

(node[shop="alcohol"](area.searchArea);
 way[shop="alcohol"](area.searchArea);)->.posts;

foreach.posts(
  out center;
  (._;>;);
  is_in;
  area._[admin_level~"[467]"];
  out ids;
);

// collect area details in 2nd step
(.posts;>;);
is_in;
area._[admin_level~"[467]"];
out;